Membuat Games FlappyBird Menggunakan Adobe Flash

Selamat malam sobat blogger kali ini saya aka shere cara membuat games FlappyBird menggunakan Adobe flash, Menurut saya game FlappyBird ini sangat untuk menguji konsentrasi, bukan saja ditujukan untuk anak-anak tetapi orang dewasa juga cocok. Pada postingan sebelumnya saya membahas beberapa tutorial.

Baca Juga:
1# Games Teka-Teki silang dan Games tangkap Telur 
2# Cara membuat games memancing
3# Games Belajar bahasa Inggris
4# Games Kuis
5# Games Puzzle 

Disini saya menggunakan adobe flash CS6. Langsung aja ikuti tutorialnya dibawah ini.

Langkah 1# Buka Adobe flash anda kemudian Pilih ActionScrip 3.0 dan klik Ok
Langkah 2# Save filen ActionScrip 3.0 dengan cara klik CTRL+S kemudian filenya beri nama FlappyBird
Langkah 3# Tekan CTRL+N (file baru) kemudian pilih ActionScript File kemudian tekan Ok
Langkah 4# Save file ActionScript File dengan cara klik CTRL+S kemudian filenya beri nama Main
Langkah 5# Brikutnya untuk Background dan gambar angryBirdsnya sobat langsung drag aja dari komputer sobat atau Pilif File -> Import -> Import To Library kemudian cari gambar.
Langkah 6# Sesuaikan ukuran gambar backround dan gambar angry Birdsnya yang sobat punya.
Langkah 7# Kemudian buat balok atau apa ya Istilahnya, Lebih jelas lihat gambar dibawah.

Keterangan : 
1 = Gambar Angry Birds (Player)
2 = Ini saya tadi katakan balok, Buat menggunakan Rectangle Tool...hehhe.... (Obstacle)
3 = Tempat Teks Score (scoretxt)

Langkah 8# Untuk Gambar Nomor 1, klik kanan kemudian pilih Convert To Symbol, kemudian beri nama Player. Lihat gambar dibawah ini. Lakukan cara yang sama untuk gambar nomor 2, tetapi namanya Obstacle.


Langkah 9# Untuk kotak teks Score Nomor 3 pilih  Properties -> Instance nama -> beri nama scoretxt -> Tekan Enter
Langkah 10# Tekan bacground kemudian pada bagian properties ada kotak yang berisi Class, pada kotak tersebut sobat ketik Main kemudian tekan CTRL+S. Lihat gambar


Langkah 11# Masukkan kode ActionScrip pada File Main.Untuk kodenya lihat dibawah ini.

package{
import flash.display.MovieClip;
import flash.events.KeyboardEvent;
import flash.ui.Keyboard;
import flash.events.Event;

public class Main extends MovieClip{

//constants
const gravity:Number = 1.5;          
const dist_btw_obstacles:Number = 300;
const ob_speed:Number = 8;
const jump_force:Number = 15;        

//variables
var player:Player = new Player();  
var lastob:Obstacle = new Obstacle();
var obstacles:Array = new Array();    
var yspeed:Number = 0;  
var score:Number = 0;  

public function Main(){
init();
}

function init():void {
//initialize all the variables
player = new Player();
lastob = new Obstacle();
obstacles = new Array();
yspeed = 0;
score = 0;

//add player to center of the stage the stage
player.x = stage.stageWidth/2;
player.y = stage.stageHeight/2;
addChild(player);

//create 3 obstacles ()
createObstacle();
createObstacle();
createObstacle();

addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
            stage.addEventListener(KeyboardEvent.KEY_UP, key_up);
}

private function key_up(event:KeyboardEvent){
if(event.keyCode == Keyboard.SPACE){
//If space is pressed then make the bird
yspeed = -jump_force;
}
}

function restart(){
if(contains(player))
removeChild(player);
for(var i:int = 0; i < obstacles.length; ++i){
if(contains(obstacles[i]) && obstacles[i] != null)
removeChild(obstacles[i]);
obstacles[i] = null;
}
obstacles.slice(0);
init();
}

function onEnterFrameHandler(event:Event){
//update player
yspeed += gravity;
player.y += yspeed;

//restart if the player touches the ground
if(player.y + player.height/2 > stage.stageHeight){
restart();
}

//Don't allow the bird to go above the screen
if(player.y - player.height/2 < 0){
player.y = player.height/2;
}

//update obstacles
for(var i:int = 0;i<obstacles.length;++i){
updateObstacle(i);
}
     
//display the score
scoretxt.text = String(score);
}

//This functions update the obstacle
function updateObstacle(i:int){
var ob:Obstacle = obstacles[i];

if(ob == null)
return;
ob.x -= ob_speed;

if(ob.x < -ob.width){

changeObstacle(ob);
}

if(ob.hitTestPoint(player.x + player.width/2,player.y + player.height/2,true)
  || ob.hitTestPoint(player.x + player.width/2,player.y - player.height/2,true)
  || ob.hitTestPoint(player.x - player.width/2,player.y + player.height/2,true)
  || ob.hitTestPoint(player.x - player.width/2,player.y - player.height/2,true)){
restart();
}

//If the bird got through the obstacle without hitting it then increase the score
if((player.x - player.width/2 > ob.x + ob.width/2) && !ob.covered){
++score;
ob.covered = true;
}
}

function changeObstacle(ob:Obstacle){
ob.x = lastob.x + dist_btw_obstacles;
ob.y = 100+Math.random()*(stage.stageHeight-200);
lastob = ob;
ob.covered = false;
}

function createObstacle(){
var ob:Obstacle = new Obstacle();
if(lastob.x == 0)
ob.x = 800;
else
ob.x = lastob.x + dist_btw_obstacles;
ob.y = 100+Math.random()*(stage.stageHeight-200);
addChild(ob);
obstacles.push(ob);
lastob = ob;
}
}
}

Langkah 12# Klik CTRL+S untuk save kemudian tekan window+enter untuk mencoba menjalankan gamesnya.
Selesai....
Untuk videonya bisa lihat dibawah ini


Sekian postingan kali ini semoga apa yang saya share ini bisa bermanfaat bagi teman-teman semua, jika ada yang kurang jelas dengan tutorial di atas silahkan tinggalkan comment diatas.Wassalam😄



Belum ada tanggapan untuk "Membuat Games FlappyBird Menggunakan Adobe Flash"

Post a Comment